AudioMasher - Propadilla by pac

# stereo
# (line 1 should make the patch stereo)
_bar var 110 bpm2dur 2 * dmetro _bar set

# prop notation: https://paulbatchelor.github.io/proj/prop.html
# triggers for bass drum, snare, bass, shakers, swell
_tbdr var _bar get 110 "+-|+-|5(-+---)+" tprop _tbdr set
_tsnr var _bar get 110 "-+|-+|2(-+-?)" tprop _tsnr set
_tbas var _bar get 110 "3(-?+)2(-+)" tprop _tbas set
_tsh1 var _bar get 110 "4(-+-+)" tprop _tsh1 set
_tsh2 var _bar get 110 "4(--++)" tprop _tsh2 set
_gswl var _bar get 4 0 count 3 eq _gswl set

_tbdr get
dup 0 0.001 0.01 tenvx 400 * 60 +
swap 0.001 0.005 0.04 tenvx # 0 *
sine dup 10 * tanh 0.1 * + dup
0.5 * dup  1 5 100 zrev
rot 0.3 * dup rot + rot rot + # add_mst

_tbdr get
dup 0.01 0.02 0.019 tenvx
swap 0.01 0.05 0.11 tenvx 0.1 *
+ 0.5 * brown * 8 0.5 0 0 dist
dup rot + rot rot + # add_stm

_tsnr get
0 0.03 (_gswl get 0.1 * 0.03 +) tenvx
1 noise 2000 800 butbr * 
0 p (_tsnr get 0 0.002 0.015 tenvx 2 * 0.7 +) * 
+ tanh 0 50 inv delay 800 1000 butbp dup 0 pset # 0 *
dup _gswl get * dup 2 3 500 zrev
rot dup rot + rot rot + # add_mst
rot + rot rot + # add_st

_tbdr get _tsnr get +
dup 0 0.02 0.019 tenvx
swap 0 0.12 0.11 tenvx 0.1 *
+ 0.5 pinknoise * # 0 *
dup rot + rot rot + # add_stm

_tbas get _tbdr get +
0 0.03 0.019 tenvx 1 noise * 
1 p (_gswl get 0.09 * 0.9 +) * + 
0 (50 0.2 1 sine dup dup * * dup dup * * 4 * +) inv 0.1 vdelay
400 tone dup 1 pset # 0 *
6000 tone 3 * 0.3 0.3 sine pan
rot + rot rot + # add_st

_tsh1 get 0 0.15 delay 0.01 0.04 0.03 tenvx
0.7 pinknoise 5000 tone 3000 buthp 3 * * # 0 *
0.3 pan
rot + rot rot + # add_st

_tsh2 get 0 0.15 delay 0.01 0.04 0.03 tenvx
0.7 pinknoise 5000 tone 800 buthp * # 0 *
2 * 0.3 pan
rot + rot rot + # add_st

2.5 * tanh 0.4 *
swap 2.5 * tanh 0.4 *

meta quick ref help

Title:
Propadilla

Author:
pac

Description:
Testing stereo. Some future improvements might help with stereo: -- remove "magic line 1", and make masher check if there are two samples on the stack instead -- add verbs add_mst, add_stm, add_st to mix stereo values on the stack

Created: 2022/05/10

Modified: 2022/05/10

License

Here are some Sporth learning resources (most of them by Paul Batchelor):

The interactive cookbook is a tutorial where you can run all the example code online (it's based on the original cookbook).
The examples demonstate a variety of Sporth ugens. Note: those that rely on external files will not work in AudioMasher.
The Soundpipe modules reference goes into more detail on the underlying function powering each Sporth ugen.
The AudioMasher collection can certainly be used as learning material.

And some information about AudioMasher: